Regnearksfunksjoner

Denne delen inneholder beskrivelser av regneark-funksjonene sammen med et eksempel.

For Ă„ bruke denne funksjonen 


Sett inn → Funksjon → Kategori Regneark


FEIL.TYPE

Returnerer et tall som representerer en spesifikk feiltype, eller feilverdien #N/A, hvis det ikke er noen feil.

ADDRESSE (ADDRESS pÄ engelsk)

Gir en celleadresse (referanse) som tekst, i fÞlge de oppgitte rad- og kolonnenumrene. Du kan finne ut om adressen er tolket som en absolutt adresse (for eksempel $A$1), relativ adresse (A1) eller i blandet form (A$1 eller $A1). Du kan ogsÄ angi navnet til regnearket.

Av hensyn til interoperabilitet stÞtter funksjonene ADRESSE og INDIREKTE (INDIRECT pÄ engelsk) en valgfri parameter for Ä angi om R1C1 adresse-notasjonen kan brukes i stedet for den vanlige A1-notasjonen.

I ADRESSE, blir parameteren satt inn som den fjerde parameteren, som flytter den valgfrie arknavn-parameteren til den femte plassering.

I INDIREKTE (INDIRECT pÄ engelsk), er parameteren lagt til som den andre parameteren.

I begge funksjoner gjelder det, at hvis argumentet blir satt inn med verdien 0, sÄ blir R1C1-notasjonen brukt. Hvis argumentet ikke er gitt eller har en annen verdi enn 0, sÄ blir A1-notasjonen brukt.

I tilfelle av R1C1-notasjon, gir ADRESSE strenger som bruker utropstegn '!' som skilletegn for arkets navn, da INDIREKTE (INDIRECT pÄ engelsk) forventer utropstegnet som skilletegn for arknavn. Begge funksjonene bruker fortsatt punktum '.' som skilletegn for arknavn med A1-notasjon.

NÄr du Äpner dokumenter fra ODF 1.0/1.1-format, vil ADRESSE-funksjonene som viser et arknavn som den fjerde parameteren skifte arknavnet til Ä bli den femte parameteren. En ny fjerde parameter med verdien 1 vil bli satt inn.

NÄr du lagrer et dokument i ODF 1.0/1.1-format, hvis ADRESSE-funksjoner har en fjerde parameter, vil denne parameteren bli fjernet.

note

Ikke lagre et regneark i det gamle ODF 1.0/1.1-formatet hvis ADRESSE-funksjonens nye fjerde parameter ble brukt med en verdi pÄ 0.


note

Den INDIREKTE-funksjonen lagres uten konvertering til ODF 1.0/1.1-format. Hvis den andre parameteren var til stede, vil en eldre versjon av Calc returnere en feil for den funksjonen.


Syntaks

ADRESSE(Rad; Kolonne [; Abs [; A1 [; "Ark"]]])

Rad tilsvarer radnummeret for cellereferansen

Kolonne tilsvarer kolonnenummeret for cellereferansen (tallet, ikke bokstaven)

ABS bestemmer typen av referanse:

1: absolutt ($A$1)

2: radreferansetype er absolutt; kolonnereferanse er relativ (A$1)

3: rad (relativ); kolonne (absolutt) ($A1)

4: relativ (A1)

A1 (valgfri) — hvis satt til 0, blir notasjonen R1C1 brukt. Hvis parameteren mangler eller er satt til en annen verdi enn 0, blir notasjonen A1 brukt.

Ark tilsvarer navnet pÄ arket. Det kan vÊre plassert i dobbelt hermetegn.

Eksempel:

=ADRESSE(1;1;2;;"Ark2") returnerer fĂžlgende: Ark2.A$1

Hvis formelen ovenfor er i celle B2 i gjeldende ark, og celle A1 i ark 2 inneholder verdien -6, kan du referere indirekte til den refererte cellen ved Ă„ bruke en funksjon i B2 ved Ă„ skrive inn =ABS(INDIRECT(B2)). Resultatet er den absolutte verdien av cellereferansen spesifisert i B2, som i dette tilfellet er 6.

ANTALL.ARK (SHEETS pÄ engelsk)

Finn antall ark i en referanse. Hvis du ikke angir noen parametere gir funksjonen antall ark i dette dokumentet.

Syntaks

ARK([Referanse])

Referanse er referansen til et ark eller et omrÄde. Denne parameteren er valgfri.

Eksempel

=ANTALL.ARK(Ark1.A1:Ark3.G12) gir 3, hvis Ark1, Ark2 og Ark3 finnes i den angitte rekkefĂžlgen.

DDE

Gir resultatet av en DDE-basert lenke. Hvis innholdet i det lenkede omrĂ„det endres, vil ogsĂ„ resultatet endres. Du mĂ„ laste regnearket pĂ„ nytt eller velge Rediger – Lenker for Ă„ se de oppdaterte lenkene. Det er ikke tillatt med lenker fra en plattform til en annen, for eksempel fra en installasjon av LibreOffice pĂ„ en Windows-maskin til et dokument opprettet pĂ„ en Linux-maskin.

Syntaks

DDE("Server"; "Fil"; "OmrÄde" [; Modus])

Server er navnet pÄ en serverapplikasjon. LibreOffice-applikasjoner har servernavnet "soffice".

Fil er det fullstendige filnavnet med sti oppgitt.

OmrÄde er omrÄdet som inneholder dataen som skal valideres.

Modus er en valgfri parameter som bestemmer den metoden som DDE-tjeneren bruker for Ă„ gjĂžre om sine data til tall.

Navn

Forskyvning

0 eller manglende

Tallformat fra cellestilten «Standard»

1

Data blir alltid fortolket som standard US engelsk-format.

2

Data blir hentet som tekst; ingen omgjĂžring til tall.


Eksempel

=DDE("soffice";"c:\office\document\data1.ods";"ark1.A1") leser innholdet i celle A1 i ark1 i LibreOffice Calc regnearkdata1.ods.

=DDE("soffice";"c:\office\document\motto.odt";"Dagens motto") returnerer et motto i cellen som inneholder denne formelen. FÞrst mÄ du skrive inn en linje i motto.odt-dokumentet som inneholder mottoteksten og definere den som den fÞrste linjen i en seksjon kalt Dagens motto (i LibreOffice Writer under Sett inn - Seksjon). Hvis mottoet er endret (og lagret) i LibreOffice Writer-dokumentet, oppdateres mottoet i alle LibreOffice Calc-celler der denne DDE-koblingen er definert.

FEILTYPE (ERRORTYPE pÄ engelsk)

Returnerer tallet som tilsvarer en feilverdi som oppstÄr i en annen celle. Ved hjelp av dette nummeret, kan du generere en feilmeldingstekst.

Dersom det oppstÄr en feil, vil funksjonen gi en logisk eller numerisk verdi.

note

Statuslinjen viser den forhÄndsdefinerte feilkoden fra LibreOffice hvis du klikker pÄ cellen som inneholder feilen.


Syntaks

FEILTYPE(Referanse)

Referanse inneholder adressen pÄ den cellen som feilen oppstÄr i.

Eksempel

Hvis celle A1 viser Err:518, gir funksjonen =FEILTYPE(A1) tallet 518.

Teknisk informasjon

Denne funksjonen er ikke en del av Open Document Format for Office-applikasjoner (OpenDocument) versjon 1.3. Del 4: Rekalkulert Formel (OpenFormula) Format-standard. Navnerommet er

ORG.OPENOFFICE.ERRORTYPE

FINN.KOLONNE (HLOOKUP pÄ engelsk)

SÞker etter en verdi og en referanse til cellene nedenfor det merkede omrÄdet. Funksjonen sjekker om den fÞrste raden i en tabell inneholder en viss verdi. Funksjonen gir sÄ verdien i en rad i tabellen, angitt av Indeks, i den samme kolonnen.

SÞket stÞtter jokertegn eller regulÊre uttrykk. Med regulÊre uttrykk aktivert, kan du skrive inn "alle.*", for eksempel for Ä finne den fÞrste plasseringen av "alle" etterfulgt av tegn. Hvis du vil sÞke etter en tekst som ogsÄ er et regulÊrt uttrykk, mÄ du enten bruke hvert regulÊrt uttrykks metategn eller operator med et "\"-tegn, eller omslutte teksten i \Q...\E. Du kan pakke inn den automatiske evalueringen av jokertegn eller regulÊre uttrykk av og pÄ i - LibreOffice Calc - Beregn .

warning

NÄr du bruker funksjoner der ett eller flere argumenter er sÞkekriterier, som representerer et regulÊrt uttrykk, er det fÞrste forsÞket Ä konvertere strengkriteriene til tall. For eksempel vil ".0" konverteres til 0.0 og sÄ videre. Hvis det lykkes, vil matchingen ikke vÊre et vanlig uttrykk, men en numerisk match. Imidlertid, nÄr du bytter til et sted der desimalskilleren ikke er punktum, fÄr det konvertering av regulÊre uttrykk Ä fungere. For Ä tvinge evalueringen av det regulÊre uttrykket i stedet for et numerisk uttrykk, bruker du et uttrykk som ikke kan feilleses som numerisk, for eksempel ". [0]" eller ". \ 0" eller "(? I) .0".


Syntaks

HLOOKUP(Oppslag; Matrise; Indeks [; SortedRangeLookup])

For en forklaring pÄ parameterne, se: VLOOKUP (kolonner og rader utveksles)

HÄndtering av tomme celler

Eksempel

Anta at vi har bygget en liten databasetabell som okkuperer celleomrÄdet A1:DO4 og inneholder grunnleggende informasjon om 118 kjemiske elementer. Den fÞrste kolonnen inneholder radoverskriftene "Element", "Symbol", "Atomnummer" og "Relativ atommasse". PÄfÞlgende kolonner inneholder relevant informasjon for hvert av elementene, sortert fra venstre til hÞyre etter atomnummer. For eksempel inneholder cellene B1:B4 "Hydrogen", "H", "1" og "1.008", mens cellene DO1:DO4 inneholder "Oganesson", "Og", "118" og "294".

A

B

C

D

...

DO

1

Element

Hydrogen

Helium

Lithium

...

Oganesson

2

Symbol

H

He

Li

...

Og

3

Atomnummer

1

2

3

...

118

4

Relativ atommasse

1.008

4.0026

6.94

...

294


=HLOOKUP("Lead"; $A$1:$DO$4; 2; 0) returnerer "Pb", symbolet for bly.

=HLOOKUP("Gull"; $A$1:$DO$4; 3; 0) returnerer 79, atomnummeret for gull.

=HLOOKUP("Karbon"; $A$1:$DO$4; 4; 0) returnerer 12.011, den relative atommassen til karbon.

FINN.NÅ (LOOKUP pĂ„ engelsk)

Returnerer innholdet i en celle enten fra en rad eller én kolonne. Eventuelt returneres den tildelte verdien (av samme indeks) i en annen kolonne og rad. I motsetning til VLOOKUP og HLOOKUP , kan sÞke- og resultatvektor vÊre i forskjellige posisjoner; de trenger ikke vÊre tilstÞtende. I tillegg mÄ sÞkevektoren for LOOKUP sorteres stigende, ellers vil sÞket ikke gi noen brukbare resultater.

note

Hvis FINN.NÅ (LOOKUP pĂ„ engelsk) ikke kan finne sĂžkekriteriet, benyttes den stĂžrste verdien i sĂžkeretningen som er mindre enn eller lik sĂžkekriteriet.


SÞket stÞtter jokertegn eller regulÊre uttrykk. Med regulÊre uttrykk aktivert, kan du skrive inn "alle.*", for eksempel for Ä finne den fÞrste plasseringen av "alle" etterfulgt av tegn. Hvis du vil sÞke etter en tekst som ogsÄ er et regulÊrt uttrykk, mÄ du enten bruke hvert regulÊrt uttrykks metategn eller operator med et "\"-tegn, eller omslutte teksten i \Q...\E. Du kan pakke inn den automatiske evalueringen av jokertegn eller regulÊre uttrykk av og pÄ i - LibreOffice Calc - Beregn .

warning

NÄr du bruker funksjoner der ett eller flere argumenter er sÞkekriterier, som representerer et regulÊrt uttrykk, er det fÞrste forsÞket Ä konvertere strengkriteriene til tall. For eksempel vil ".0" konverteres til 0.0 og sÄ videre. Hvis det lykkes, vil matchingen ikke vÊre et vanlig uttrykk, men en numerisk match. Imidlertid, nÄr du bytter til et sted der desimalskilleren ikke er punktum, fÄr det konvertering av regulÊre uttrykk Ä fungere. For Ä tvinge evalueringen av det regulÊre uttrykket i stedet for et numerisk uttrykk, bruker du et uttrykk som ikke kan feilleses som numerisk, for eksempel ". [0]" eller ". \ 0" eller "(? I) .0".


Syntaks

LOOKUP(Lookup; SearchVector [; ResultVector])

Lookup er verdien av en hvilken som helst type som skal ses etter; oppgis enten direkte eller som referanse.

SearchVector er et omrÄde med én rad eller én kolonne som skal sÞkes i.

ResultVector er et annet omrÄde med én rad eller én kolonne som resultatet av funksjonen er hentet fra. Resultatet er cellen til resultatvektoren med samme indeks som forekomsten funnet i sÞkevektoren.

HÄndtering av tomme celler

Eksempel

=LOOKUP(A1;D1:D100;F1:F100) sÞker i den tilsvarende cellen i omrÄdet D1:D100 etter tallet du skrev inn i A1. For forekomsten som ble funnet, bestemmes indeksen, for eksempel den 12. cellen i dette omrÄdet. Deretter returneres innholdet i den 12. cellen som verdien av funksjonen (i resultatvektoren).

FINN.RAD (VLOOKUP pÄ engelsk)

Vertikalt sÞk med referanse til tilstÞtende celler til hÞyre. Denne funksjonen sjekker om en bestemt verdi finnes i den fÞrste kolonnen i en matrise. Funksjonen returnerer deretter verdien i samme rad i kolonnen navngitt av Indeks. Hvis parameteren Sortert er utelatt eller satt til TRUE eller én, antas det at dataene er sortert i stigende rekkefÞlge. I dette tilfellet, hvis det eksakte oppslag ikke blir funnet, vil den siste verdien som er mindre enn kriteriet bli returnert. Hvis Sortert er satt til USANN eller null, mÄ et eksakt samsvar finnes, ellers vil feilen Feil: Verdi ikke tilgjengelig bli resultatet. Med en verdi pÄ null trenger ikke dataene Ä sorteres i stigende rekkefÞlge.

SÞket stÞtter jokertegn eller regulÊre uttrykk. Med regulÊre uttrykk aktivert, kan du skrive inn "alle.*", for eksempel for Ä finne den fÞrste plasseringen av "alle" etterfulgt av tegn. Hvis du vil sÞke etter en tekst som ogsÄ er et regulÊrt uttrykk, mÄ du enten bruke hvert regulÊrt uttrykks metategn eller operator med et "\"-tegn, eller omslutte teksten i \Q...\E. Du kan pakke inn den automatiske evalueringen av jokertegn eller regulÊre uttrykk av og pÄ i - LibreOffice Calc - Beregn .

warning

NÄr du bruker funksjoner der ett eller flere argumenter er sÞkekriterier, som representerer et regulÊrt uttrykk, er det fÞrste forsÞket Ä konvertere strengkriteriene til tall. For eksempel vil ".0" konverteres til 0.0 og sÄ videre. Hvis det lykkes, vil matchingen ikke vÊre et vanlig uttrykk, men en numerisk match. Imidlertid, nÄr du bytter til et sted der desimalskilleren ikke er punktum, fÄr det konvertering av regulÊre uttrykk Ä fungere. For Ä tvinge evalueringen av det regulÊre uttrykket i stedet for et numerisk uttrykk, bruker du et uttrykk som ikke kan feilleses som numerisk, for eksempel ". [0]" eller ". \ 0" eller "(? I) .0".


Syntaks

=VLOOKUP(Oppslag; Matrise; Indeks [; SortedRangeLookup])

Oppslag er verdien av en hvilken som helst type som ble sett etter i den fĂžrste kolonnen i matrisen.

Matrise er referansen, som skal omfatte minst like mange kolonner som tallet som sendes i Index-argumentet.

Indeks er kolonnenummeret i omrÄdet som inneholder verdien som skal returneres. Den fÞrste kolonnen har tallet 1.

SortedRangeLookup er en valgfri parameter som indikerer om den fÞrste kolonnen i matrisen inneholder omrÄdegrenser i stedet for vanlige verdier. I denne modusen returnerer oppslaget verdien i raden med fÞrste kolonne med verdi lik eller mindre enn Oppslag. Den kan for eksempel inneholde datoer da en skatteverdi var endret, og verdiene representerer derfor startdatoer for en periode da en spesifikk skatteverdi var effektiv. Derfor vil sÞk etter en dato som er fravÊrende i den fÞrste matrisekolonnen, men som faller mellom noen eksisterende grensedatoer, gi den laveste av dem, slik at du kan finne ut at dataene er effektive til den sÞkte datoen. Skriv inn den boolske verdien USANN eller null hvis den fÞrste kolonnen ikke er en omrÄdegrenseliste. NÄr denne parameteren er SANN eller ikke gitt, mÄ den fÞrste kolonnen i matrisen sorteres i stigende rekkefÞlge. Sorterte kolonner kan sÞkes mye raskere og funksjonen returnerer alltid en verdi, selv om sÞkeverdien ikke ble matchet nÞyaktig, hvis den er stÞrre enn den laveste verdien i den sorterte listen. I usorterte lister mÄ sÞkeverdien samsvare nÞyaktig. Ellers vil funksjonen returnere #N/A med meldingen: Feil: Verdi ikke tilgjengelig.

HÄndtering av tomme celler

Eksempel

Du vil legge inn nummeret til en rett pÄ menyen i celle A1, og navnet pÄ retten skal vises som tekst i nabocellen (B1) umiddelbart. Nummer til navn-tildelingen finnes i D1:E100-arrayen. D1 inneholder 100, E1 inneholder navnet GrÞnnsaksuppe, og sÄ videre, for 100 menyelementer. Tallene i kolonne D er sortert i stigende rekkefÞlge; Derfor er den valgfrie parameteren Sortert ikke nÞdvendig.

Skriv inn fĂžlgende formel i B1:

=FINN.RAD(A1; D1:E100; 2)

SÄ snart du skriver inn et tall i A1 vil B1 vise den tilsvarende teksten i den andre kolonnen med referanse D1:E100. Hvis du legger inn et ikke-eksisterende tall, vises teksten med neste tall nede. For Ä forhindre dette, skriv inn FALSE som siste parameter i formelen slik at det genereres en feilmelding nÄr et ikke-eksisterende tall legges inn.

FORSKYVNING (OFFSET pÄ engelsk)

Gir verdien til en celle som ligger et visst antall rader og kolonner fra et gitt referansepunkt.

Denne funksjonen beregnes alltid pÄ nytt hver gang en ny beregning skjer.

Syntaks

OFFSET(Referanse; Rader; Kolonner [; HĂžyde [; Bredde]])

Referanse er cellen hvorfra funksjonen leter etter den nye referansen.

Rader er antall rader referansen ble korrigert oppover (negativ verdi) eller ned.

Rader er antall rader referansen ble korrigert oppover (negativ verdi) eller ned.

HÞyde (valgfri) er den valgfrie loddrette hÞyden pÄ et omrÄde som begynner ved den nye referanseposisjonen.

Bredde (valgfri) er den vannrette bredden for et omrÄde som begynner ved den nye referanseposisjonen.

Argumentene HĂžyde og Bredde kan ikke fĂžre til null eller et negativt antall av rader eller kolonner.

Argumentene HĂžyde og Bredde kan ikke fĂžre til null eller et negativt antall av rader eller kolonner.

I LibreOffice Calc-funksjoner kan parametre merket som «valgfri» kun utelates hvis ingen parameter fÞlger etter. For eksempel i en funksjon med fire parametre, hvor de siste to parametrene er merket som «valgfri», kan du utelade parameter 4 eller parametrene 3 og 4, men du kan ikke utelate parameter 3 alene.

Eksempel

=FORSKYVNING(A1; 2; 2) gir verdien i celle C3 (A1 flyttet med to rader og to kolonner nedover). Hvis C3 inneholder verdien 100 gir denne funksjonen verdien 100.

=FORSKYVNING(B2:C3;1;1) gir en referanse til B2:C3 flyttet 1 rad ned og en kolonne til hĂžyre (C3:D4).

=FORSKYVNING(B2:C3;-1;-1) gir en referanse til B2:C3 flyttet 1 rad opp og en kolonne til venstre (A1:B2).

=FORSKYVNING(B2:C3;0;0;3;4) gir en referanse til B2:C3 med stĂžrrelsen endret til 3 rader og 4 kolonner (B2:E4).

=FORSKYVNING(B2:C3;1;0;3;4) gir en referanse til B2:C3 flyttet en rad ned og med stĂžrrelsen endret til 3 rader og 4 kolonner (B2:E4).

=SUMMER(FORSKYVNING(A1;2;2;5;6)) bestemmer summen av omrÄdet som starter i celle C3 og har en hÞyde pÄ 5 rader og en bredde av 6 kolonner (omrÄde=C3:H7).

note

Hvis Bredde eller HÞyde er gitt, returnerer OFFSET-funksjonen en celleomrÄdereferanse. Hvis Referanse er en enkeltcellereferanse og bÄde Bredde og HÞyde er utelatt, returneres en enkeltcellereferanse.


HENTPIVOTDATA

GETPIVOTDATA-funksjonen returnerer en resultatverdi fra en pivottabell. Verdien adresseres ved hjelp av felt- og elementnavn, sÄ den forblir gyldig hvis oppsettet til pivottabellen endres.

Syntaks

To forskjellige syntaksdefinisjoner kan brukes:

GETPIVOTDATA(MÄlfelt; pivottabell[; Felt 1; Element 1][; ... [Felt 126; Element 126]])

eller

GETPIVOTDATA(pivottabell; Begrensninger)

Syntaks nr. 2 antas Ä vÊre brukt hvis eksakt to parametre er gitt, hvor den fÞrste parameteren er en referanse til en celle eller et celleomrÄde. Det fÞrste syntaks antas Ä vÊre brukt i alle andre tilfeller. Funksjonsveiviseren viser det fÞrste syntaks.

FĂžrste syntaks

TargetField er en streng som velger ett av pivottabellens datafelt. Strengen kan vÊre navnet pÄ kildekolonnen, eller datafeltnavnet som vist i tabellen (som "Sum - Salg").

pivottabell er en referanse til en celle eller et celleomrÄde som er plassert i en pivottabell eller inneholder en pivottabell. Hvis celleomrÄdet inneholder flere pivottabeller, brukes tabellen som ble opprettet sist.

Hvis ingen Felt n / Vare n-par er gitt, returneres totalsummen. Ellers legger hvert par til en begrensning som resultatet mÄ tilfredsstille. Felt n er navnet pÄ et felt fra pivottabellen. Element n er navnet pÄ et element fra det feltet.

Hvis pivottabellen bare inneholder en enkelt resultatverdi som oppfyller alle begrensningene, eller et subtotalresultat som oppsummerer alle samsvarende verdier, returneres dette resultatet. Hvis det ikke er noe samsvarende resultat, eller flere uten en delsum for dem, returneres en feil. Disse betingelsene gjelder for resultater som er inkludert i pivottabellen.

Hvis kildedataene inneholder oppfÞringer som er skjult av innstillingene i pivottabellen, ignoreres de. RekkefÞlgen av felt/element-parene er ikke signifikant. Felt- og elementnavn skiller ikke mellom store og smÄ bokstaver.

Hvis det ikke er gitt noen begrensning for et filter, brukes feltets valgte verdi implisitt. Hvis en begrensning for et filter er gitt, mÄ den samsvare med feltets valgte verdi, ellers returneres en feil. Filtre er feltene Þverst til venstre i en pivottabell, fylt ut ved hjelp av "Filtre"-omrÄdet i pivottabelllayoutdialogen. Fra hvert filter kan en vare (verdi) velges, noe som betyr at kun den varen er inkludert i beregningen.

Subtotalverdier fra pivottabellen brukes bare hvis de bruker funksjonen "auto" (bortsett fra nÄr det er spesifisert i begrensningen, se Andre syntaks nedenfor).

Andre syntaks

pivottabell har samme betydning som i den fĂžrste syntaksen.

Begrensninger er en mellomromseparert liste. Bidrag kan siteres (enkelt sitat). Hele strengen mÄ vÊre omgitt av anfÞrselstegn (doble anfÞrselstegn), med mindre du refererer til strengen fra en annen celle.

En av oppfÞringene kan vÊre datafeltnavnet. Datafeltnavnet kan utelates hvis pivottabellen inneholder kun ett datafelt, ellers mÄ det vÊre til stede.

Hver av de andre oppfĂžringene spesifiserer en begrensning i formen Felt[element] (med bokstaver [ og ]), eller bare Element hvis elementnavnet er unikt innenfor alle feltene som brukes i pivottabellen.

Et funksjonsnavn kan legges til pÄ formen felt[element;funksjon], hvilket betyr at kriteriene bare passer pÄ delsumverdier som bruker denne funksjonen. De mulige funksjonsnavnene er Summer, Antall, Middel, Maks, Min, Produkt, Antall (kun tall), Stdav, Stdavp, Varians, og Variansp. Det skille ikke mellom store og smÄ bokstaver.

HYPERLENKE

NÄr du trykker pÄ en celle som inneholder HYPERLENKE-funksjonen vil hypelenken Äpnes.

Hvis du bruker den valgfrie CellValue-parameteren, finner formelen URL-en og viser deretter teksten eller tallet.

tip

For Ă„ Ă„pne en hyperlenken celle med tastaturet, velg cellen, trykk «F2» for Ă„ gĂ„ i redigeringsmodus, flytt pekeren foran hyperlenken, trykke «Shift+F10» og velg sÄÅpne hyperlenke.


Syntaks

HYPERLINK("URL" [; CellValue])

URL spesifiserer koblingsmÄlet. Den valgfrie CellValue-parameteren er teksten eller et tall som vises i cellen og vil bli returnert som resultat. Hvis CellValue-parameteren ikke er spesifisert, vises URL i celleteksten og returneres som resultat.

Tallet 0 returneres for tomme celler og matriseelementer.

Eksempel

=HYPERLINK("http://www.example.org") viser teksten "http://www.example.org" i cellen og kjÞrer hyperkoblingen http://www.example .org nÄr du klikker.

=HYPERLINK("http://www.example.org";"Klikk her") viser teksten "Klikk her" i cellen og kjÞrer hyperkoblingen http://www.example.org nÄr du klikker.

=HYPERLINK("http://www.example.org";12345) viser tallet 12345 og kjÞrer hyperkoblingen http://www.example.org nÄr den klikkes.

=HYPERLINK($B4) der celle B4 inneholder http://www.example.org. Funksjonen legger til http://www.example.org til URL-en til hyperkoblingscellen og returnerer den samme teksten som brukes som formelresultat.

=HYPERLINK("http://www.";"Klikk ") & "example.org" viser teksten Click example.org i cellen og kjÞrer hyperkoblingen http://www.example .org nÄr du klikker.

=HYPERLINK("#Ark1.A1";"GĂ„ til toppen") viser teksten GĂ„ til toppen og hopper til cellen Ark1.A1 i dette dokumentet.

=HYPERLINK("file:///C:/writer.odt#Specification";"GĂ„ til Writer-bokmerke") viser teksten "GĂ„ til Writer-bokmerke", laster det angitte tekstdokumentet og hopper for Ă„ bokmerke "Spesifikasjon".

=HYPERLINK("file:///C:/Documents/";"Open Documents folder") viser teksten "Open Documents folder" og viser mappeinnholdet ved Ă„ bruke standard filbehandling system.

INDEKS (INDEX pÄ engelsk)

INDEKS gir innholdet av en celle, angitt enten ved rad og kolonne eller ved et navngitt omrÄde. Avhengig av sammenhengen gir INDEKS enten innhold eller en referanse.

Syntaks

INDEX(Referanse [; Rad [; Kolonne [; OmrÄde]]])

Referanse er en cellereferanse, enten skrevet inn direkte eller ved Ä bruke navnet pÄ et omrÄde. Hvis referansen bestÄr av flere omrÄder, mÄ du angi referansen eller omrÄdenavnet i parentes.

Rad (valgfri) representerer radnummeret til referanseomrÄdet som skal returneres som en verdi. Hvis null (ingen spesifikk rad) returneres alle refererte rader

Kolonne (valgfri) representerer kolonnenummeret til referanseomrÄdet som skal returneres som en verdi. Hvis null (ingen spesifikk kolonne) returneres alle refererte kolonner.

OmrÄde (valgfri) tilsvarer indeksen for underomrÄdet som refererer til flere omrÄder.

Eksempel

=INDEKS(Priser;4;1) gir verdien fra rad 4 og kolonne 1 av databaseomrĂ„det angitt i Data → Angi som Priser.

=INDEX(SumX;4;1) returnerer verdien fra omrĂ„det SumX i rad 4 og kolonne 1 som definert i Ark - navngitt OmrĂ„der og uttrykk – Definer.

=INDEKS(A1:B6;1) gir en referanse til den fĂžrste raden i A1:B6.

=INDEKS(A1:B6;0;1) gir en referanse til den fĂžrste kolonnen i A1:B6.

=INDEX((multi);4;1) indikerer verdien i rad 4 og kolonne 1 i (flere) omrĂ„det, som du navnga under Ark - navngitt OmrĂ„der og uttrykk – Definer som multi. MultippelomrĂ„det kan bestĂ„ av flere rektangulĂŠre omrĂ„der, hver med en rad 4 og kolonne 1. Hvis du nĂ„ vil kalle den andre blokken i dette multiple omrĂ„det, skriv inn tallet 2 som range-parameter.

=INDEKS(A1:B6;1;1) angir verdien Þverst i det venstre hjÞrnet av omrÄdet A1:B6.

=INDEKS((multi);0;0;2) gir en referanse til det andre omrÄdet av multiomrÄdet.

INDIREKTE (INDIRECT pÄ engelsk)

Gir referansen som er angitt ved en tekststreng. Du kan ogsÄ bruke denne funksjonen for Ä finne omrÄdet til den samsvarende strengen.

Denne funksjonen beregnes alltid pÄ nytt hver gang en ny beregning skjer.

Av hensyn til interoperabilitet stÞtter funksjonene ADRESSE og INDIREKTE (INDIRECT pÄ engelsk) en valgfri parameter for Ä angi om R1C1 adresse-notasjonen kan brukes i stedet for den vanlige A1-notasjonen.

I ADRESSE, blir parameteren satt inn som den fjerde parameteren, som flytter den valgfrie arknavn-parameteren til den femte plassering.

I INDIREKTE (INDIRECT pÄ engelsk), er parameteren lagt til som den andre parameteren.

I begge funksjoner gjelder det, at hvis argumentet blir satt inn med verdien 0, sÄ blir R1C1-notasjonen brukt. Hvis argumentet ikke er gitt eller har en annen verdi enn 0, sÄ blir A1-notasjonen brukt.

I tilfelle av R1C1-notasjon, gir ADRESSE strenger som bruker utropstegn '!' som skilletegn for arkets navn, da INDIREKTE (INDIRECT pÄ engelsk) forventer utropstegnet som skilletegn for arknavn. Begge funksjonene bruker fortsatt punktum '.' som skilletegn for arknavn med A1-notasjon.

NÄr du Äpner dokumenter fra ODF 1.0/1.1-format, vil ADRESSE-funksjonene som viser et arknavn som den fjerde parameteren skifte arknavnet til Ä bli den femte parameteren. En ny fjerde parameter med verdien 1 vil bli satt inn.

NÄr du lagrer et dokument i ODF 1.0/1.1-format, hvis ADRESSE-funksjoner har en fjerde parameter, vil denne parameteren bli fjernet.

note

Ikke lagre et regneark i det gamle ODF 1.0/1.1-formatet hvis ADRESSE-funksjonens nye fjerde parameter ble brukt med en verdi pÄ 0.


note

Den INDIREKTE-funksjonen lagres uten konvertering til ODF 1.0/1.1-format. Hvis den andre parameteren var til stede, vil en eldre versjon av Calc returnere en feil for den funksjonen.


Syntaks

INDIRECT(Ref [; A1])

Referanse tilsvarer en referanse til en celle eller et omrÄde (i tekstform) som verdien skal returneres fra.

A1 (valgfri) — hvis satt til 0, blir notasjonen R1C1 brukt. Hvis parameteren mangler eller er satt til en annen verdi enn 0, blir notasjonen A1 brukt.

note

Hvis du Äpner et Excel-regneark som bruker indirekte adresser beregnet fra strengfunksjoner, vil ikke arkadressene bli oversatt automatisk. Excel-adressen i INDIRECT("[filnavn]arknavn!"&B1) blir for eksempel ikke konvertert til Calc-adressen i INDIRECT("filnavn#arknavn."&B1).


Eksempel

=INDIREKTE(A1) er lik 100 hvis A1 inneholder C108 som en referanse og celle C108 inneholder en verdi pÄ 100.

=SUMMER(INDIREKTE("A1:" & ADRESSE(1;3))) summerer cellene i omrÄdet fra A1 opp til cellen hvis adresse er angitt ved rad 1 og kolonne 3. Det vil si: A1:C1 er oppsummert.

KOLONNE (COLUMN pÄ engelsk)

Returnerer kolonnenummeret til en cellereferanse. Hvis referansen er en celle, returneres kolonnenummeret til cellen; hvis parameteren er et celleomrÄde, returneres de tilsvarende kolonnenumrene i en enkeltrads matrise hvis formelen er angittsom en matriseformel. Hvis COLUMN-funksjonen med en omrÄdereferanseparameter ikke brukes for en matriseformel, bestemmes bare kolonnenummeret til den fÞrste cellen i omrÄdet.

Syntaks

COLUMN([Referanse])

Referanse er referansen til en celle eller celleomrÄde hvis fÞrste kolonnenummer finnes.

Hvis ingen referanse skrives inn, blir kolonnenummeret for cellen hvor formelen er skrevet inn funnet.LibreOffice Calc angir automatisk henvisningen til den gjeldende cellen.

Eksempel

=KOLONNE(A1) er lik 1. Kolonne A er den fĂžrste kolonnen i tabellen.

=KOLONNE(C3:E3) er lik 3. Kolonne C er den tredje kolonnen i tabellen.

=KOLONNE(D3:G10) gir 4, fordi kolonne D er den fjerde kolonnen i tabellen, og KOLONNE-funksjonen ikke er brukt som en matriseformel. (I dette tilfellet brukes den fĂžrste verdien i matrisen alltid som resultat.)

{=KOLONNE(B2:B7)} og =KOLONNE(B2:B7) gir hver isÊr 2 fordi referansen bare inneholder kolonne B som den annen kolonne i tabellen. Fordi enkelt-kolonneomrÄder bare har et kolonnenummer, gjÞr det ingen forskjell om formelen blir brukt som en matriseformel.

==KOLONNE() gir 3 hvis formelen ble skrevet inn i kolonne C.

{=KOLONNE(Kanin)} gir enkeltradmatrisen (3; 4) hvis "Kanin" er det navngitte omrÄdet (C1:D3).

KOLONNER (COLUMNS pÄ engelsk)

Gir antall kolonner i den oppgitte referansen.

Syntaks

KOLONNER(Matrise)

Matrise er referansen til et celleomrÄde hvis totale antall kolonner skal finnes. Argumentet kan ogsÄ vÊre en enkelt celle.

Eksempel

=Rader(B5) gir 1, fordi en celle inneholder kun en enkelt rad.

=KOLONNER(A1:C5) er lik 3. Henvisningen omfatter tre Kolonner.

=KOLONNER(Kanin) gir 2 hvisKanin er det navngitte omrÄdet (C1:D3).

OMRÅDER (AREAS pĂ„ engelsk)

Gir antall individuelle omrÄder som er med i et sammensatt omrÄde. Et dataomrÄde kan bestÄ av Ún enkelcelle eller et sammenhengende celleomrÄde.

Funksjonen forventer et enkelt argument. Hvis du oppgir flere omrÄder, mÄ du sette dem inn i flere parenteser. Flere omrÄder kan angis ved Ä bruke semikolon (;) som skillelinje, men dette blir automatisk konvertert til tilde (~)-operatoren. Tilden brukes til Ä slÄ sammen omrÄder.

Syntaks

OMRÅDER(Referanse)

Referanse representerer referansen til en celle eller et celleomrÄde.

Eksempel

=AREAS((A1:B3;F2;G1)) returnerer 3, da det er en referanse til tre celler og/eller omrÄder. Etter inntasting blir dette konvertert til =AREAS((A1:B3~F2~G1)).

=OMRÅDER(Alt) gir 1 hvis du har angitt et omrĂ„de ved navn «Alt» under Data → Angi omrĂ„de..

RAD

Returnerer radnummeret til en cellereferanse. Hvis referansen er en celle, returnerer den radnummeret til cellen. Hvis referansen er et celleomrÄde, returnerer den tilsvarende radnummer i en én-kolonne Matrise hvis formelen er angitt som en matriseformel. Hvis ROW-funksjonen med en omrÄdereferanse ikke brukes i en matriseformel, vil bare radnummeret til den fÞrste omrÄdecellen bli returnert.

Syntaks

ROW([Referanse])

Referanse er en celle, et omrÄde eller navnet pÄ et omrÄde.

Hvis du ikke angir en referanse, vil radnummeret for cellen hvor formlen er skrevet inn bli funnet.LibreOffice Calc angir automatisk referansen til den gjeldende cellen.

Eksempel

RAD(B3) gir 3, fordi referansen henviser til den tredje raden i tabellen.

{=RAD(D5:D8)} gir matrisen med enkeltkolonnen (5, 6, 7, 8), fordi den angitte referansen inneholder radene 5 til 8.

=RAD(D5:D8) gir 5 fordi REKKE-funksjonen ikke blir brukt som matriseformel og bare nummeret pÄ den fÞrste raden i referansen returneres.

{=KOLONNE(B2:B7)} og =KOLONNE(B2:B7) gir hver isÊr 2 fordi referansen bare inneholder kolonne B som den annen kolonne i tabellen. Fordi enkelt-kolonneomrÄder bare har et kolonnenummer, gjÞr det ingen forskjell om formelen blir brukt som en matriseformel.

=RAD() gir 3 hvis formelen ble skrevet inn i rad 3.

{=RAD(Kanin)} gir matrisen med enkeltkolonnen (1, 2, 3) hvis "Kanin" er det navngitte omrÄdet (C1:D3).

RADER (ROWS pÄ engelsk)

Gir antall rader i en referanse eller tabell.

Syntaks

RADER(Matrise)

Matrise er referansen eller det navngitte omrÄdet som totale antall rader skal oppdages for.

Eksempel

=Rader(B5) gir 1, fordi en celle inneholder kun en enkelt rad.

=RADER(A10:B12) gir 3.

=RADER(Kanin) gir 3, hvis "Kanin" er det navngitte omrÄdet (C1:D3).

SAMMENLIGNE (MATCH pÄ engelsk)

Gir den relative posisjonen til et element i en tabell, der elementet svarer til en viss verdi. Funksjonen gir posisjonen, som et nummer, til verdien funnet i sĂžketabellen.

Syntaks

MATCH(SĂžk; LookupArray [; Type])

SĂžk er verdien som skal sĂžkes etter i en rad eller en kolonne.

LookupArray er referansen det sĂžkes etter. En oppslagsmatrise kan vĂŠre en enkelt rad eller kolonne, eller en del av en enkelt rad eller kolonne.

Type kan ha verdiene 1, 0 eller -1. Hvis Type = 1 eller hvis denne valgfrie parameteren mangler, antas det at den fĂžrste kolonnen i sĂžkematrisen er sortert i stigende rekkefĂžlge. Hvis Type = -1, antas det at kolonnen er sortert i synkende rekkefĂžlge. Dette tilsvarer samme funksjon i Microsoft Excel.

Hvis Type = 0, finnes bare eksakte treff. Hvis sÞkekriteriet blir funnet mer enn én gang, returnerer funksjonen indeksen til den fÞrste samsvarende verdien. Bare hvis Type = 0 kan du sÞke etter regulÊre uttrykk (hvis aktivert i beregningsalternativer) eller jokertegn (hvis aktivert i beregningsalternativer).

Hvis Type = 1 eller den tredje parameteren mangler, returneres indeksen for den siste verdien som er mindre eller lik sĂžkekriteriet. For Type = -1, returneres indeksen til den siste verdien som er stĂžrre eller lik.

SÞket stÞtter jokertegn eller regulÊre uttrykk. Med regulÊre uttrykk aktivert, kan du skrive inn "alle.*", for eksempel for Ä finne den fÞrste plasseringen av "alle" etterfulgt av tegn. Hvis du vil sÞke etter en tekst som ogsÄ er et regulÊrt uttrykk, mÄ du enten bruke hvert regulÊrt uttrykks metategn eller operator med et "\"-tegn, eller omslutte teksten i \Q...\E. Du kan pakke inn den automatiske evalueringen av jokertegn eller regulÊre uttrykk av og pÄ i - LibreOffice Calc - Beregn .

warning

NÄr du bruker funksjoner der ett eller flere argumenter er sÞkekriterier, som representerer et regulÊrt uttrykk, er det fÞrste forsÞket Ä konvertere strengkriteriene til tall. For eksempel vil ".0" konverteres til 0.0 og sÄ videre. Hvis det lykkes, vil matchingen ikke vÊre et vanlig uttrykk, men en numerisk match. Imidlertid, nÄr du bytter til et sted der desimalskilleren ikke er punktum, fÄr det konvertering av regulÊre uttrykk Ä fungere. For Ä tvinge evalueringen av det regulÊre uttrykket i stedet for et numerisk uttrykk, bruker du et uttrykk som ikke kan feilleses som numerisk, for eksempel ". [0]" eller ". \ 0" eller "(? I) .0".


Eksempel

=MATCH(200;D1:D100) sÞker i omrÄdet D1:D100, som er sortert etter kolonne D, etter verdien 200. SÄ snart denne verdien er nÄdd, vises tallet av raden den ble funnet i returneres. Hvis en hÞyere verdi blir funnet under sÞket i kolonnen, returneres nummeret til forrige rad.

SHEET

Returnerer arknummeret til enten en referanse eller en streng som representerer et arknavn. Hvis du ikke angir noen parametere, er resultatet arknummeret til regnearket som inneholder formelen.

Syntaks

SHEET([Referanse])

Referanse er valgfri og er referansen til en celle, et omrÄde eller et arknavn.

Eksempel

=ARK(Ark2.A1) returnerer 2 hvis Ark2 er det andre arket i regnearkdokumentet.

=SHEET("Ark3") returnerer 3 hvis Ark3 er det tredje arket i regnearkdokumentet.

STIL (STYLE pÄ engelsk)

Bruker en stil pÄ cellen som inneholder formelen. Etter en viss tid kan en annen stil brukes. Denne funksjonen returnerer alltid verdien 0, slik at du kan legge den til en annen funksjon uten Ä endre verdien. Sammen med CURRENT-funksjonen kan du bruke en farge pÄ en celle avhengig av verdien. For eksempel: =...+STYLE(IF(CURRENT()>3;"rÞd";"grÞnn")) bruker stilen "rÞd" pÄ cellen hvis verdien er stÞrre enn 3, ellers stilen "grÞnn" blir brukt. Begge celleformatene, "rÞd" og "grÞnn" mÄ defineres pÄ forhÄnd.

note

STYLE-funksjonen bÞr ikke brukes uten tvingende grunn, dens formÄl er bruk med asynkrone tilleggsfunksjoner for Ä visuelt varsle om tilgjengeligheten av et resultat. I nesten alle andre tilfeller er bruk av betinget formatering i stedet et bedre valg.


Syntaks

STIL("Stil" [; Tid [; "Stil2"]])

Stil er navnet pÄ en cellestil tildelt cellen. Stilnavn mÄ tastes inn i hermetegn.

Tid er en valgfri tidsperiode i sekunder. Hvis denne parameteren mangler, vil ikke stilen bli endret etter et bestemt tidsrom.

Stil2 er den valgfrie cellestilen tildelt cellen etter et bestemt tidsrom. Hvis denne parameteren mangler vil "Standard" bli benyttet.

I LibreOffice Calc-funksjoner kan parametre merket som «valgfri» kun utelates hvis ingen parameter fÞlger etter. For eksempel i en funksjon med fire parametre, hvor de siste to parametrene er merket som «valgfri», kan du utelade parameter 4 eller parametrene 3 og 4, men du kan ikke utelate parameter 3 alene.

Eksempel

=STIL("Usynlig";60;"Standard") formaterer cellen i gjennomsiktig format i 60 sekunder etter dokumentet ble omberegnet (eller lest inn), deretter vil standardformat bli brukt. Begge celleformatene mÄ vÊre angitt pÄ forhÄnd.

Siden STYLE() har en numerisk returverdi pÄ null, blir denne returverdien lagt til en streng. Dette kan unngÄs ved Ä bruke T() som i fÞlgende eksempel:

="Tekst"&T(STIL"minStil"))

Se ogsÄ GJELDENDE() for et annet eksempel.

Teknisk informasjon

Denne funksjonen er ikke en del av Open Document Format for Office-applikasjoner (OpenDocument) versjon 1.3. Del 4: Rekalkulert Formel (OpenFormula) Format-standard. Navnerommet er

ORG.OPENOFFICE.STYLE

VELG (CHOOSE pÄ engelsk)

Bruker en indeks for Ă„ hente en verdi fra en liste med opptil 30 verdier.

Syntaks

VELG(Indeks; Verdi 1 [; Verdi 2 [; ... [; Verdi 30]]])

Indeks er en referanse eller et tall mellom 1 og 30, som angir hvilke verdier som skal tas fra listen.

Verdi 1, Verdi 2, ..., Verdi 30 er listen over verdier angitt som en referanse til en celle eller som individuelle verdier.

Eksempel

=VELG(A1; B1; B2; B3; "I dag"; "I gÄr"; "I morgen"), gir for eksempel innholdet av celle B2 til A1 = 2; for A1 = 4 vil funksjonen returnere teksten "I dag".